玩家死亡事件

简介 ​

由基岩版命令社区 (BCC) Discord 提供

本系统将在玩家死亡时执行您指定的命令。

设置 ​

在聊天栏输入以下命令：

/scoreboard objectives add wiki:alive dummy

如果您使用函数并希望在世界初始化时自动添加该记分项，请按照首次世界加载中描述的流程操作。

系统 ​

## 设置玩家状态
### 非存活状态
scoreboard players set @a[scores={wiki:alive=!2}] wiki:alive 0
### 存活状态
scoreboard players set @e[type=player] wiki:alive 1

## 在此处添加您的命令（示例）
execute as @a[scores={wiki:alive=0}] run say 我死了

## 标记已对死亡玩家执行命令
scoreboard players set @a[scores={wiki:alive=0}] wiki:alive 2

这里我们使用了/execute - say命令作为示例，但您可以使用任何喜欢的命令，数量不限。

只需确保遵循给定的顺序，并正确应用scores={wiki:alive=0}选择器参数。

原理说明 ​

• wiki:alive=0 玩家处于非存活状态（死亡）
• wiki:alive=1 玩家处于存活状态
• wiki:alive=2 玩家已死亡且我们已对其执行了指定命令

各命令的作用：

1. 命令1： 默认将所有玩家标记为"非存活"(0)
   • 我们会忽略分数为2的情况，否则玩家死亡时我们想要运行的命令会多次触发
2. 命令2： 将所有存活玩家标记为"存活"(1)
   • @e选择器让我们能专门定位存活的玩家
   • @a选择器会定位所有玩家，无论是否存活
3. 命令3： 现在存活玩家分数为1，死亡玩家分数为0，我们将利用这一点在玩家死亡(0)时运行指定命令
4. 命令4： 由于我们希望玩家死亡时只执行一次命令，我们会将其分数设为2。如果不这样做，命令会在玩家重生前重复执行

Tick JSON ​

如果使用函数而非命令方块，必须将on_death函数添加到tick.json中才能循环持续运行。可以通过在每个字符串后加逗号来添加多个文件到tick.json。更多信息请参考函数文档。

{
  "values": [
    "wiki/event/players/on_death"
  ]
}

如果使用函数，您的包文件夹结构如下：

替代方案 ​

此方法在Minecraft 1.19.50版本引入新的/execute语法后得以实现。

• 请确保添加wiki:q.is_dead记分项：
  • /scoreboard objectives add wiki:q.is_dead dummy

## 设置玩家状态
### 未死亡状态
scoreboard players set @e[type=player] wiki:q.is_dead 0
### 死亡状态
execute as @a at @s unless entity @e[type=player,r=0.01] run scoreboard players add @s wiki:q.is_dead 1

## 在此处添加您的命令（示例）
### 在死亡位置召唤盔甲架
execute as @a[scores={wiki:q.is_dead=1}] at @s run summon armor_stand "尸体" ~~~
### 在聊天栏显示死亡消息
execute as @a[scores={wiki:q.is_dead=1..}] run say 我已死亡且尚未重生...

状态说明：

• wiki:q.is_dead=0 玩家未死亡（存活）
• wiki:q.is_dead=1 玩家刚刚死亡（用于"触发"动作）
• wiki:q.is_dead=1.. 玩家仍处于死亡状态（用于重复动作）

各命令的作用：

1. 命令1： 将所有存活玩家标记为"未死亡"(0)
2. 命令2： 如果玩家0.01方块半径内没有其他存活玩家，则将其标记为死亡(1)
   • 逻辑是只有玩家自己才能出现在离自己如此近的半径内。两个或更多玩家自己（不使用/tp命令）精确站在同一点的概率接近于零
3. 命令3,4： 这些是可修改/扩展的示例命令（针对每种状态）