Bedrock Wiki
新手入门指南
JSON UI
Meta
NBT
世界生成
动画控制器
命令
实体
战利品、配方与交易
文档
方块
服务器
概念
物品
视觉效果
粒子效果
脚本编写
虚拟现实

MBE - Max的方块实体

MBE - Max的方块实体

简介 ​

由基岩版命令社区(BCC) Discord提供

这个方法由Reddit用户u/Maxed_Out10开发，允许你使用盔甲架和一系列连续的/playanimation命令来创建近乎完美的Minecraft方块实体复制品。

为保留创作者署名，社区将此方法命名为"Max的方块实体"或简称MBE。

注意事项：

  1. 每个方块实体需要使用1个盔甲架。因此过多的盔甲架（如同任何实体）可能导致服务器卡顿。
  2. 玩家仍然可以穿过它们，也可以与之交互（如果未被限制）。
  3. 虽然方块实体可能在一个位置渲染，但其实际碰撞箱会有轻微偏移。

视频演示 ​

设置步骤 ​

在聊天框中输入：

  1. /summon armor_stand ~~~ 81 ~ default "Grumm"
    • 我们将Y轴（水平）旋转设为81以与普通Minecraft方块网格对齐。
    • 必须命名为'Grumm'以避免方块纹理反转。

TIP

  • 潜行状态下右键点击（在MCPE上长按）盔甲架6次可将其置于'娱乐'姿势。
  • 这样做可以省略下方系统中的第一个命令。
  • 仅在希望减少系统命令数量时使用此方法。
  1. 最后，将所需方块物品放入盔甲架的主手。

TIP

  • /replaceitem entity @e[name="Grumm"] slot.weapon.offhand 0 <物品ID>
    • 可以替代手动放置，将此命令用于将方块物品放入盔甲架的副手，防止玩家拿走物品。

系统实现 ​

BP/functions/wiki/mbe/render.mcfunction
yaml
## 手臂对齐
playanimation @e[type=armor_stand,name="Grumm"] animation.armor_stand.entertain_pose null 0 "0" wiki:align.arms

## 迷你方块尺寸
playanimation @e[type=armor_stand,name="Grumm"] animation.player.move.arms.zombie null 0 "0" wiki:size.mini_block

## 完整方块（可选）
### 尺寸调整
playanimation @e[type=armor_stand,name="Grumm"] animation.ghast.scale null 0 "0" wiki:size.full_block
### 对齐调整
playanimation @e[type=armor_stand,name="Grumm"] animation.fireworks_rocket.move null 0 "0" wiki:align.full_block

## 固定盔甲架位置
execute as @e[type=armor_stand,name="Grumm"] at @s run tp ~~~

## 隐藏盔甲架本体
effect @e[type=armor_stand,name="Grumm"] invisibility infinite 1 true

commandBlockChain6

各命令功能说明 ​

  1. 自动将盔甲架设为'娱乐'姿势以对齐手臂。若已手动设置可跳过此命令。
  2. 必需命令。调整尺寸呈现为迷你方块。
  3. 可选命令。 调整尺寸呈现为完整方块。
  4. 可选命令。 对齐完整方块尺寸的MBE。
    • 若不需要完整方块尺寸可跳过3和4。
  5. 锁定盔甲架位置防止下方方块被移除时掉落。
  6. 隐藏盔甲架本体。

注意：提供控制器名称允许我们堆叠动画而不覆盖前一个。例如：

  • wiki:align.full_block（其中wiki是命名空间）。

不强制要求使用上述相同的控制器名称。但这有助于避免与其他playanimation命令冲突。

旋转与对齐 ​

注意：这些旋转命令（当物品放置在主手时）需要通过命令方块一次性触发。

完整方块
yaml
# 朝北
/tp @e[type=armor_stand,name="Grumm",c=1] ~-1.1245 ~0.2260 ~-0.097 81

# 朝南
/tp @e[type=armor_stand,name="Grumm",c=1] ~1.1245 ~0.2260 ~0.097 260

# 朝东
/tp @e[type=armor_stand,name="Grumm",c=1] ~0.097 ~0.2260 ~-1.1245 171

# 朝西
/tp @e[type=armor_stand,name="Grumm",c=1] ~-0.097 ~0.2260 ~1.1245 350
迷你方块
yaml
# 朝北
/tp @e[type=armor_stand,name="Grumm",c=1] ~-0.417~-0.5 ~-0.035 81

# 朝南
/tp @e[type=armor_stand,name="Grumm",c=1] ~0.417 ~-0.5 ~0.035 260

# 朝东
/tp @e[type=armor_stand,name="Grumm",c=1] ~0.035 ~-0.5 ~-0.417 171

# 朝西
/tp @e[type=armor_stand,name="Grumm",c=1] ~-0.035 ~-0.5 ~0.417 350
楼梯
yaml
# 朝北
/tp @e[type=armor_stand,name="Grumm",c=1] ~-0.097 ~0.2325 ~1.1245 350

# 朝南
/tp @e[type=armor_stand,name="Grumm",c=1] ~0.097 ~0.2325 ~-1.1245 171

# 朝东
/tp @e[type=armor_stand,name="Grumm",c=1] ~-1.1245 ~0.2325 ~-0.097 81

# 朝西
/tp @e[type=armor_stand,name="Grumm",c=1] ~1.1245 ~0.2325 ~0.097 260
下半砖
yaml
# 朝北
/tp @e[type=armor_stand,name="Grumm",c=1] ~-0.097 ~0.2325 ~1.1245 350

# 朝南
/tp @e[type=armor_stand,name="Grumm",c=1] ~0.097 ~0.2325 ~-1.1245 171

# 朝东
/tp @e[type=armor_stand,name="Grumm",c=1] ~-1.1245 ~0.2325 ~-0.097 81

# 朝西
/tp @e[type=armor_stand,name="Grumm",c=1] ~1.1245 ~0.2325 ~0.097 260
上半砖
yaml
# 朝北
/tp @e[type=armor_stand,name="Grumm",c=1] ~-1.1245 ~0.484 ~-0.097 81

# 朝南
/tp @e[type=armor_stand,name="Grumm",c=1] ~1.1245 ~0.484 ~0.097 260

# 朝东
/tp @e[type=armor_stand,name="Grumm",c=1] ~0.097 ~0.484 ~-1.1245 171

# 朝西
/tp @e[type=armor_stand,name="Grumm",c=1] ~-0.097 ~0.484 ~1.1245 350

保存与加载MBE ​

  1. 保存时运行：

    • /execute at @e[type=armor_stand,name="Grumm",c=1] run structure save wiki:mbe ~~~ ~~~ true disk false

  2. 加载时运行：

    • /structure load wiki:mbe <目标坐标: x y z>

注意：结构名称wiki:mbe可根据需要修改。

贡献者

编辑 MBE - Max的方块实体