移动状态检测

前言
移动检测
行走与疾跑区分

前言

由基岩版命令社区(BCC) Discord提供

图片来源：非官方Minecraft Wiki - CC BY-NC-SA 3.0

这些命令技术可帮助您检测玩家/实体的特定"状态"，并执行相应命令。

注意：如需更高性能和精度的方案，建议使用动画控制器

移动检测

该技术可检测目标是否正在移动，即使是最细微的动作也能捕捉。

已知问题：

使用望远镜缩放时或受到6级及以上缓慢效果时无法检测移动。
跳跃会导致检测触发两次。

命令：

首先添加计分板目标：
- /scoreboard objectives add wiki:q.is_moving dummy

BP/functions/wiki/detect_state/player/is_moving.mcfunction

yaml

## 移动检测
### 标记为静止
execute as @a at @s positioned ~~10000~ if entity @e[type=leash_knot,r=0.1252] run scoreboard players set @s wiki:q.is_moving 0
### 标记为移动
execute as @a at @s positioned ~~10000~ unless entity @e[type=leash_knot, r=0.1252] run scoreboard players add @s wiki:q.is_moving 1

## 更新标记点
### 删除旧标记
execute as @e[type=leash_knot] at @s unless entity @s[y=-80, dy=9974] run kill @s
### 创建新标记
execute at @a positioned ~~10000~ run summon leash_knot ~~~

## 自定义命令示例
execute as @a[scores=wiki:q.is_moving=0}] run say 我没有移动
execute as @a[scores=wiki:q.is_moving=1}] run say 我开始移动了
execute as @a[scores=wiki:q.is_moving=1..}] run say 我仍在移动

commandBlockChain7

必须按照相同顺序执行命令，并正确使用scores选择器参数。

状态说明：

wiki:q.is_moving=0 目标静止
wiki:q.is_moving=1 目标开始移动（用于触发动作）
wiki:q.is_moving=1.. 目标持续移动（用于重复动作）

命令原理：

命令1：检测玩家上方是否有拴绳结，无位移则标记为静止(0)
- 拴绳结是具备抗重力特性的实体，在本系统中作为静态标记点
命令2：若无拴绳结则判定发生位移，标记为移动(1)
- 持续移动会使分数不断增加，便于执行单次触发命令
命令3：清理旧标记点以减少实体造成的卡顿
- 使用体积过滤而非名称过滤（拴绳结无法命名）
命令4：在玩家上方10000格处生成新标记点
命令5-7：可修改的状态响应示例命令

行走与疾跑区分

如需单独检测行走和疾跑状态，可使用以下技术：

已知问题：

状态效果和附魔可能影响检测准确性。

BP/functions/wiki/detect_state/player/is_moving.mcfunction

yaml

## 移动检测
### 标记为静止
execute as @a at @s positioned ~~10000~ if entity @e[type=leash_knot,r=0.1252] run scoreboard players set @s wiki:q.is_moving 0
### 标记为移动
execute as @a at @s positioned ~~10000~ unless entity @e[type=leash_knot,r=0.1252] run scoreboard players add @s wiki:q.is_moving 1

## 行走检测
### 标记为非行走
scoreboard players set @a wiki:q.is_walking 0
### 标记为行走
execute as @a at @s positioned ~~10000~ if entity @e[type=leash_knot,rm=0.21585,r=0.2805] run scoreboard players set @s wiki:q.is_walking 1

## 疾跑检测
### 标记为非疾跑
scoreboard players set @a wiki:q.is_sprinting 0
### 标记为疾跑
execute as @a at @s positioned ~~10000~ if entity @e[type=leash_knot, rm=0.2806,r=0.9] run scoreboard players set @s wiki:q.is_sprinting 1

## 更新标记点
### 删除旧标记
execute as @e[type=leash_knot] at @s unless entity @s[y=-80,dy=9974] run kill @s
### 创建新标记
execute at @a positioned ~~10000~ run summon leash_knot ~~~

## 自定义命令示例
execute as @a[scores={wiki:q.is_walking=0}] run say 我没有行走
execute as @a[scores={wiki:q.is_walking=1}] run say 我正在行走